========================== PROGRAMME DE CALCUL DU THEME NATAL =============

	'theme.bas

	DEFINT A-Z
	DECLARE FUNCTION Z360# (x AS DOUBLE)
	DECLARE FUNCTION Z24# (x AS DOUBLE)
	DECLARE FUNCTION Z360r# (x AS DOUBLE)
	DECLARE FUNCTION z360s! (x AS SINGLE)
	DECLARE FUNCTION Formule# (oblic AS DOUBLE, temps AS DOUBLE, phi AS DOUBLE, coef AS DOUBLE)
	DECLARE SUB Coordonn (theme AS ANY, a AS DOUBLE, e AS DOUBLE, i AS DOUBLE, m AS DOUBLE, w AS DOUBLE, d AS DOUBLE, lg AS DOUBLE, lt AS DOUBLE, dec AS DOUBLE)
	DECLARE SUB AutreCoordonn (t AS ANY)
	DECLARE FUNCTION Atan2# (x AS DOUBLE, y AS DOUBLE)
	DECLARE FUNCTION Asin# (x AS DOUBLE)
	DECLARE SUB JJulien (theme AS ANY)
	DECLARE FUNCTION MumSigne% (x AS DOUBLE)
	DECLARE FUNCTION JourJulien# (annee%, mois%, jour%, heure!)

	DECLARE SUB Caltheme (theme AS ANY)
	DECLARE SUB Init ()
	DECLARE SUB Angles (theme AS ANY)
	DECLARE SUB Lentes (theme AS ANY)
	DECLARE SUB Lune (theme AS ANY)
	DECLARE SUB Pointsfictifs (theme AS ANY)
	DECLARE SUB Rapides (theme AS ANY)
	DECLARE SUB Saspects (theme AS ANY)
	DECLARE SUB Soleil (theme AS ANY)
	DECLARE SUB Splanmais (theme AS ANY)
	DECLARE SUB VoirTheme (theme AS ANY, sortie AS INTEGER)

	TYPE typetheme
	   annee AS INTEGER
	   mois AS INTEGER
	   jour AS INTEGER
	   heure AS SINGLE
	   t0 AS DOUBLE              'temps jour j
	   n0 AS DOUBLE
	   t1 AS DOUBLE              ' temps jour j+1
	   n1 AS DOUBLE
	   htu AS DOUBLE             ' TU en heures decimales
	   latrad AS DOUBLE          ' latitude du lieu en radians
	   lonrad AS DOUBLE          ' longitude du lieu en radians
	   lonheur AS DOUBLE         ' longitude du lieu en heures decimales
	   armc AS DOUBLE            ' en radians
	   oblic AS DOUBLE           ' obliquite ecliptique ( en radians)
	   xsol AS DOUBLE
	   ysol AS DOUBLE
	END TYPE

	'Ce P. de QBasic n'accepte pas les tableaux 
	'comme elements d'une structure
	DIM SHARED LongPlanetes(16) AS SINGLE
	DIM SHARED LatPlanetes(10) AS SINGLE
	DIM SHARED ArPlanetes(10) AS SINGLE
	DIM SHARED Decplanetes(10) AS SINGLE
	DIM SHARED AziPlanetes(10) AS SINGLE
	DIM SHARED HautPlanetes(10) AS SINGLE
	DIM SHARED PasPlanetes(10) AS SINGLE
	DIM SHARED PlEnsignes(16) AS INTEGER
	DIM SHARED PlEnMaisons(16) AS INTEGER
	DIM SHARED LongAngles(13) AS SINGLE
	DIM SHARED AnglesEnSignes(13) AS INTEGER
	DIM SHARED aspects(16, 16) AS SINGLE

	DIM theme AS typetheme
	DIM Theme1 AS typetheme

	DIM SHARED orbes(3, 13, 14) AS INTEGER
	DIM SHARED numang(3) AS INTEGER
	DIM SHARED coefang(3) AS SINGLE
	DIM SHARED coef2ang(3) AS SINGLE
	DIM SHARED plan(16) AS STRING
	DIM SHARED signe(12) AS STRING
	DIM SHARED denoasp(8) AS STRING
 
	CONST pi = 3.14159265358979#
	CONST degrad = pi / 180#
	CONST radeg = 180# / pi

	CONST format11 = "     \                  \:  ##ø ##'  \          \ \\ (Pas= ###ø##')"
	CONST format1 = "     \                  \:  ##ø ##'  \          \ "
	CONST format2 = "          Maison  ##:    ##ø ##'  \          \"
	CONST format3 = "          \             \ en  Maison  ##"
	CONST format4 = "   \            \  \         \   \                 \ (orbe:####.#ø)"
	CONST format5 = "   \        \ Lat= ##ø##' Dec= ###ø##' AR= ###ø##' Haut= ###ø##' Az= ###ø##'"

	CONST conj = 1, car = 2, sext = 3
	CONST vrai = -1, faux = 0
	CONST ecran = 5, imprimante = 6

    CLS
	  OPEN "scrn:" FOR RANDOM AS #ecran
	  OPEN "lpt1:" FOR OUTPUT AS #imprimante

	  'J.M. BIGARD
	  theme.jour = 17
	  theme.mois = 5
	  theme.annee = 1954
	  theme.heure = 10.5  '(11H30 LEG, 10h30 TU)
	  theme.htu = theme.heure 'htu est un 'double' heure est un 'single'
	  theme.latrad = 48.3 * degrad  '(48ø18')
	  theme.lonheur = .272  '(4ø05' Est)  en heures (<0 si Ouest)
	  '4ø 05'= 4.083ø= 4.083 * 4 = 16.33 minutes = 16.33/60 = 0.272 heures
	  Init
	  Caltheme theme
	  VoirTheme theme, ecran
    END

DEFSNG A-Z
'
'
'
'
'
'
	 SUB Angles (theme AS typetheme)
	   DIM latr AS DOUBLE, arm AS DOUBLE, oe AS DOUBLE
	   DIM xt AS DOUBLE, yt AS DOUBLE
	   DIM lmc AS DOUBLE, temps AS DOUBLE, ad AS DOUBLE
	   DIM r1 AS DOUBLE, r2 AS DOUBLE, r3 AS DOUBLE
	   DIM x1 AS DOUBLE, f1 AS DOUBLE, f2 AS DOUBLE
	   DIM i AS INTEGER, j AS INTEGER, ag AS INTEGER
	   DIM xx AS DOUBLE
		latr = theme.latrad '   latitude du lieu en radians
		arm = theme.armc
		oe = theme.oblic    '    obliquite ecliptique
		xt = COS(arm) * COS(oe)
		yt = SIN(arm)
		lmc = Z360#(Atan2#(yt, xt) * radeg)
		LongAngles(10) = lmc
		AnglesEnSignes(10) = MumSigne%(lmc)
		temps = arm + pi / 2
		ad = Z360#(Formule#(oe, temps, latr, 1#) * radeg)
		LongAngles(1) = ad
		AnglesEnSignes(1) = MumSigne%(ad)
		r3 = TAN(oe) * TAN(latr)
		FOR i = 0 TO 3
		   r1 = arm + coef2ang(i)
		   f1 = 0
		   f2 = 1
		   IF (i > 1) THEN
			f1 = pi
			f2 = -1!
		   END IF
		   FOR j = 1 TO 10
			x1 = SIN(r1) * r3 * (-f2)
			x1 = -ATN(x1 / SQR(-x1 * x1 + 1)) + pi / 2
			x1 = x1 / coefang(i)
			r2 = arm + f1 + x1 * f2
			r1 = r2
		   NEXT j
		   ag = numang(i)
		   xt = COS(oe) * COS(r2)
		   yt = SIN(r2)
		   xx = Z360#(Atan2#(yt, xt) * radeg)'en degres
		   LongAngles(ag) = xx
		   AnglesEnSignes(ag) = MumSigne%(xx)
		NEXT i
		xx = Z360#(LongAngles(10) + 180) ' 10-4
		LongAngles(4) = xx
		AnglesEnSignes(4) = MumSigne%(xx)

		xx = Z360#(LongAngles(12) + 180) ' 12-6
		LongAngles(6) = xx
		AnglesEnSignes(6) = MumSigne%(xx)

		xx = Z360#(LongAngles(11) + 180) ' 11-5
		LongAngles(5) = xx
		AnglesEnSignes(5) = MumSigne%(xx)

		xx = Z360#(LongAngles(1) + 180) '1-7
		LongAngles(7) = xx
		AnglesEnSignes(7) = MumSigne%(xx)

		xx = Z360#(LongAngles(2) + 180) '2-8
		LongAngles(8) = xx
		AnglesEnSignes(8) = MumSigne%(xx)

		xx = Z360#(LongAngles(3) + 180) '3-9
		LongAngles(9) = xx
		AnglesEnSignes(9) = MumSigne%(xx)

		LongAngles(13) = LongAngles(1)
		AnglesEnSignes(13) = AnglesEnSignes(1)

		LongPlanetes(11) = LongAngles(1)
		PlEnsignes(11) = AnglesEnSignes(1)
		LongPlanetes(12) = LongAngles(10)
		PlEnsignes(12) = AnglesEnSignes(10)
	 END SUB

'
'
'
'
'
'
	FUNCTION Asin# (x AS DOUBLE)
	   Asin# = ATN(x / (SQR(1# - x * x) + 1D-30))
	END FUNCTION

'
'
'
'
'
'
	 FUNCTION Atan2# (y AS DOUBLE, x AS DOUBLE) '''as double
	  DIM angle AS DOUBLE
	    IF (y = 0) THEN y = .00000000175453#
	    IF (x = 0) AND (y > 0) THEN
		  Atan2# = pi / 2#
		  EXIT FUNCTION
	    END IF
	    IF (x = 0) AND (y < 0) THEN
		  Atan2# = pi * 1.5#
		  EXIT FUNCTION
	    END IF
	    angle = ATN(y / x)
	    IF (angle < 0) THEN angle = angle + pi
	    IF (y < 0) THEN angle = angle + pi
	    Atan2# = angle
	 END FUNCTION

DEFINT A-Z
'
'
'
'
'
'
	 SUB AutreCoordonn (t AS typetheme)
	   DIM x AS DOUBLE, y AS DOUBLE
	   DIM lg AS SINGLE, lt AS SINGLE, dec AS SINGLE
	   DIM ci AS SINGLE, si AS SINGLE, oe AS SINGLE
	   DIM ar AS SINGLE, ha AS SINGLE, az AS SINGLE
	   DIM anglehor AS SINGLE
	    oe = t.oblic    '    obliquite ecliptique
	    ci = COS(oe)
	    si = SIN(oe)
	    FOR pl = 1 TO 10
		  '***  Ar (Ascension Droite)
		  lg = LongPlanetes(pl) * degrad
		  lt = LatPlanetes(pl) * degrad
		  dec = Decplanetes(pl) * degrad
		  y = ci * SIN(lg) - si * TAN(lt)
		  x = COS(lg)
		  ar = Atan2#(y, x)
		  ArPlanetes(pl) = Z360#(ar * radeg)

		  '*** Hauteur
		  anglehor = ar - t.armc
		  ha = Asin#(SIN(t.latrad) * SIN(dec) + COS(t.latrad) * COS(dec) * COS(anglehor))
		  HautPlanetes(pl) = ha * radeg

		  '***  Azimut
		  y = COS(dec) * SIN(anglehor)
		  x = SIN(t.latrad) * COS(dec) * COS(anglehor) - COS(t.latrad) * SIN(dec)
		  az = Atan2#(y, x)
		  AziPlanetes(pl) = Z360#(az * radeg)
	    NEXT pl
	 END SUB

DEFSNG A-Z
'
'
'
'
'
'
	 SUB Caltheme (theme AS typetheme)
	  DIM i AS INTEGER, delta AS SINGLE
	  DIM Longplan1(10), Longplan2(10)
	  DIM Theme1 AS typetheme
	  CONST MaxDeltaLong = 14 'la lune fait au max 14ø en un jour
	    theme.t0 = JourJulien#(theme.annee, theme.mois, theme.jour, theme.heure)
	    theme.n0 = theme.t0 * 36525#

	    'Calcul theme jour apres (pour calcul pas des planetes)
	    Theme1.n0 = theme.n0 + 1
	    Theme1.t0 = Theme1.n0 / 36525#

	    Soleil Theme1
	    Lune Theme1
	    Rapides Theme1
	    Lentes Theme1
	    FOR i = 1 TO 10
		 Longplan2(i) = LongPlanetes(i)
	    NEXT i

	    'Calcul theme du jour
	    Pointsfictifs theme
	    Soleil theme
	    Lune theme
	    Rapides theme
	    Lentes theme
	    Angles theme
	    Splanmais theme
	    Saspects theme
	    AutreCoordonn theme
	    FOR i = 1 TO 10
		 Longplan1(i) = LongPlanetes(i)
	    NEXT i
	    FOR i = 1 TO 10
		  delta = Longplan2(i) - Longplan1(i)
		  IF (ABS(delta) > MaxDeltaLong) THEN
			delta = delta + SGN(delta) * 360
		  END IF
		  PasPlanetes(i) = delta
	    NEXT i
	END SUB

'
'
'
'
'
'
	 SUB Coordonn (theme AS typetheme, a AS DOUBLE, e AS DOUBLE, i AS DOUBLE, m AS DOUBLE, w AS DOUBLE, d AS DOUBLE, lg AS DOUBLE, lt AS DOUBLE, dec AS DOUBLE)
	   ' a:demi grand axe
	   ' e:exentricite
	   ' i: inclinaison
	   ' Anomalie exentrique (u), Anomalie vraie (v)
	   ' Rayon Vecteur (r), Latitude Helio (b)
	   ' Longitude sur l'orbite (lo), longitude ecliptique (lg)
	   DIM u AS DOUBLE, v AS DOUBLE, r AS DOUBLE, sb AS DOUBLE
	   DIM b AS DOUBLE, lo AS DOUBLE, zz AS DOUBLE, xs AS DOUBLE
	   DIM ys AS DOUBLE, xx AS DOUBLE, yy AS DOUBLE
	   DIM ww AS DOUBLE, le AS DOUBLE
	   DIM ci AS SINGLE, si AS SINGLE, oe AS SINGLE
	   DIM j AS INTEGER
		'longitude
		u = m
		FOR j = 1 TO 10
		   u = m + e * SIN(u)
		NEXT j
		v = 2# * ATN(SQR((1# + e) / (1# - e)) * TAN(u / 2#))
		r = a - a * e * COS(u)
		sb = SIN(i) * SIN(v + w - d)
		b = Asin#(sb)
		IF (b > pi) THEN b = 2 * pi - b
		lo = v + w
		ww = lo - d
		le = ATN(COS(i) * SIN(ww) / COS(ww)) + d
		IF (COS(ww) < 0) THEN le = le + pi
		zz = r * SIN(b)
		xs = theme.xsol
		ys = theme.ysol
		xx = xs + r * COS(b) * COS(le)
		yy = ys + r * COS(b) * SIN(le)
		lg = ATN(yy / xx)
		IF (xx < 0) THEN lg = lg + pi
	 
		'latitude
		lt = Asin#(zz / (SQR(xx * xx + yy * yy + zz * zz)))

		'declinaison
		oe = theme.oblic    '    obliquite ecliptique
		ci = COS(oe)
		si = SIN(oe)
		dec = Asin#(ci * SIN(lt) + si * COS(lt) * SIN(lg))

	 END SUB

'
'
'
'
'
'
	FUNCTION Formule# (oblic AS DOUBLE, temps AS DOUBLE, phi AS DOUBLE, coef AS DOUBLE)       '''as double
	   DIM xt AS DOUBLE, yt AS DOUBLE
		xt = COS(oblic) * COS(temps) - SIN(oblic) * TAN(phi) * coef
		yt = SIN(temps)
		Formule# = Atan2#(yt, xt)
	END FUNCTION

'
'
'
'
'
'
	 SUB Init
	   DIM fic AS INTEGER, nbcol AS INTEGER, nblig AS INTEGER
	   DIM nbskip AS INTEGER, acomment AS INTEGER
	   DIM i AS INTEGER, j AS INTEGER, k AS INTEGER, l AS INTEGER
	   DIM comment AS STRING

		numang(0) = 11
		numang(1) = 12
		numang(2) = 2
		numang(3) = 3

		coefang(0) = 3!
		coefang(1) = 1.5
		coefang(2) = 1.5
		coefang(3) = 3!

		coef2ang(0) = .523599
		coef2ang(1) = 1.0471976#
		coef2ang(2) = 2.0943951#
		coef2ang(3) = 2.617994
 
		plan(1) = "Soleil"
		plan(2) = "Lune"
		plan(3) = "Mercure"
		plan(4) = "Venus"
		plan(5) = "Mars"
		plan(6) = "Jupiter"
		plan(7) = "Saturne"
		plan(8) = "Uranus"
		plan(9) = "Neptune"
		plan(10) = "Pluton"
		plan(11) = "Ascendant"
		plan(12) = "Milieu du Ciel"
		plan(13) = "Noeud As Lune Corr."
		plan(14) = "Lune Noire corr."
		plan(15) = "Noeud As Lune moy."
		plan(16) = "Lune Noire moy."
   
		signe(1) = "Belier"
		signe(2) = "Taureau"
		signe(3) = "Gemeaux"
		signe(4) = "Cancer"
		signe(5) = "Lion"
		signe(6) = "Vierge"
		signe(7) = "Balance"
		signe(8) = "Scorpion"
		signe(9) = "Sagittaire"
		signe(10) = "Capricorne"
		signe(11) = "Verseau"
		signe(12) = "Poissons"

		denoasp(1) = "nil"
		denoasp(2) = "Sextile"
		denoasp(3) = "nil"
		denoasp(4) = "nil"
		denoasp(5) = "Carre"
		denoasp(6) = "Trigone"
		denoasp(7) = "Opposition"
		denoasp(8) = "Conjonction"

		fic = FREEFILE
		OPEN "orbes.txt" FOR INPUT AS #fic
		INPUT #fic, nblig
		INPUT #fic, nbcol
		INPUT #fic, nbskip
		INPUT #fic, acomment
		'Nb : DIM SHARED orbes(3, 13, 14) AS INTEGER
		FOR i = conj TO sext
		   FOR k = 1 TO nbskip
			LINE INPUT #fic, comment
		   NEXT k
		   FOR j = 1 TO nblig  '13
			FOR l = 1 TO nbcol '14
			   INPUT #fic, orbes(i, j, l)
			NEXT l
			IF (acomment) THEN LINE INPUT #fic, comment
		   NEXT j
		NEXT i
		CLOSE #fic
	 END SUB

DEFINT A-Z
'
'
'
'
'
'
	 FUNCTION JourJulien# (annee, mois, jour, heure!)
	    ye = annee
	    mm = mois
	    dd = jour
	    x# = annee + mois / 10! + jour / 10000! + heure! / 1000000!
	    IF (mm <= 2) THEN
		  ye = ye - 1
		  mm = mm + 12
	    END IF
	    IF (x# > 1583.101512#) THEN
		  aj = ye \ 100
		  bj = 2 - aj + aj \ 4
		ELSE
		  bj = 0
	    END IF
	    jj# = INT(365.25# * ye) + INT(30.6001 * (mm + 1))
	    jj# = jj# + dd + 1720994.5# + bj + heure! / 24!
	    JourJulien# = (jj# - 2415020#) / 36525#
	END FUNCTION

DEFSNG A-Z
'
'
'
'
'
'
	 SUB Lentes (theme AS typetheme)
	   DIM a AS DOUBLE, e AS DOUBLE, i AS DOUBLE
	   DIM m AS DOUBLE, w AS DOUBLE, d AS DOUBLE
	   DIM lg AS DOUBLE, lt AS DOUBLE, dec AS DOUBLE
	   DIM k AS DOUBLE, sk AS DOUBLE, ck AS DOUBLE, t AS DOUBLE
	    t = theme.t0

	    'Jupiter
	    k = 2.349761# + .711349# * t
	    sk = SIN(k)
	    ck = COS(k)
	    a = 5.202561# - .000026# * ck
	    e = .048335# + .000164# * t + .000361# * sk + .000129# * ck
	    i = .022842# - .000099# * t
	    m = 3.932721# + 52.965368# * t + .007442# * ck + .003176# * sk
	    w = .222022# + .028099# * t - .007368# * ck + .002607# * sk
	    d = 1.735615# + .017637# * t
	    Coordonn theme, a, e, i, m, w, d, lg, lt, dec
	    lg = Z360#(lg * radeg)
	    PlEnsignes(6) = MumSigne%(lg)
	    LongPlanetes(6) = lg
	    LatPlanetes(6) = lt * radeg
	    Decplanetes(6) = dec * radeg

	  
	    ' Saturne
	    a = 9.554747# + .000057# * sk + .000293# * ck
	    e = .055892# - .000346# * t - .000793# * sk + .001388# * ck
	    i = .043503# - .000068# * t
	    m = 3.062463# + 21.320095# * t - .0383# * sk - .014478# * ck
	    w = 1.589963# + .034181# * t + .024079# * sk + .014295# * ck
	    d = 1.968564# + .01524# * t
	    Coordonn theme, a, e, i, m, w, d, lg, lt, dec
	    lg = Z360#(lg * radeg)
	    PlEnsignes(7) = MumSigne%(lg)
	    LongPlanetes(7) = lg
	    LatPlanetes(7) = lt * radeg
	    Decplanetes(7) = dec * radeg

	  
	    ' Uranus
	    k = 4.958028# + .148533# * t
	    sk = SIN(k)
	    ck = COS(k)
	    a = 19.21814# - .003824# * ck
	    e = .046344# - .000027# * t - .000335# * sk + .0021# * ck
	    i = .013482# + .000011# * t
	    m = 1.26796# + 7.476626# * t - .030255# * sk - .005875# * ck
	    w = 2.99409# + .025908# * t + .045305# * sk + .007306# * ck
	    d = 1.28418# + .008703# * t
	    Coordonn theme, a, e, i, m, w, d, lg, lt, dec
	    lg = Z360#(lg * radeg)
	    PlEnsignes(8) = MumSigne%(lg)
	    LongPlanetes(8) = lg
	    LatPlanetes(8) = lt * radeg
	    Decplanetes(8) = dec * radeg


	    ' Neptune
	    a = 30.10957# + .01058# * ck
	    e = .008997# + .000006# * t + .00044# * sk + .000426# * ck
	    i = .031054# - .000167# * t
	    m = .658524# + 3.81287# * t - .056901# * sk + .047519# * ck
	    w = .815546# + .024863# * t + .046558# * sk - .048498# * ck
	    d = 2.280821# + .01918 * t
	    Coordonn theme, a, e, i, m, w, d, lg, lt, dec
	    lg = Z360#(lg * radeg)
	    PlEnsignes(9) = MumSigne%(lg)
	    LongPlanetes(9) = lg
	    LatPlanetes(9) = lt * radeg
	    Decplanetes(9) = dec * radeg

	  
	    ' Pluton
	    a = 39.43871#
	    e = .250236#
	    i = .299681#
	    m = 4.000635 + 2.536813 * t#
	    w = 3.909712#
	    d = 1.915324#
	    Coordonn theme, a, e, i, m, w, d, lg, lt, dec
	    lg = Z360#(lg * radeg)
	    PlEnsignes(10) = MumSigne%(lg)
	    LongPlanetes(10) = lg
	    LatPlanetes(10) = lt * radeg
	    Decplanetes(10) = dec * radeg

	  END SUB

'
'
'
'
'
'
	 SUB Lune (theme AS typetheme)
	  DIM d AS DOUBLE, n  AS DOUBLE
	  DIM f AS DOUBLE, ll AS DOUBLE, m AS DOUBLE
	  DIM t  AS DOUBLE
	  DIM latlu AS DOUBLE, latlur AS DOUBLE, lonlur AS DOUBLE
	  DIM sdeclu AS DOUBLE, declur AS DOUBLE
	  DIM ci AS DOUBLE, si AS DOUBLE
	    t = theme.t0
	    m = 6.256583522# + 628.3019457# * t - .000002618# * t * t
	    d = 6.121524185# + 7771.377193# * t - .0000242407# * t * t
	    n = 5.168002334# + 8328.691104# * t - .00019877# * t * t
	    f = .196364085# + 8433.466288# * t - .0000557536# * t * t
	    ll = 4.719966618# + 8399.709143# * t - .00001939# * t * t
	    ll = ll + .109759# * SIN(n)
	    ll = ll + .022236# * SIN(d + d - n)
	    ll = ll + .01149# * SIN(d + d)
	    ll = ll + .003728# * SIN(n + n)
	    ll = ll - .003239# * SIN(m)
	    ll = ll - .001996# * SIN(f + f)
	    ll = ll + .001026# * SIN(d + d - n - n)
	    ll = ll + .0009990002# * SIN(d + d - m - n)
	    ll = ll + .000931# * SIN(d + d + n)
	    ll = ll + .000801# * SIN(d + d - m)
	    ll = ll + .000716# * SIN(n - m)
	    ll = ll - .000606# * SIN(d)
	    ll = ll - .000535# * SIN(m + n)
	    ll = ll + .000267# * SIN(d + d - f - f)
	    ll = ll - .000219# * SIN(f + f + n)
	    ll = ll - .000192# * SIN(f + f - n)
	    lonlur = ll
	    ll = ll * radeg
	    ll = Z360#(ll)
	    latlu = 18461.48 * SIN(f)
	    latlu = latlu + 1010.19 * SIN(n + f)
	    latlu = latlu + 999.69 * SIN(n - f)
	    latlu = latlu + 61.91 * SIN(n + n + f)
	    latlu = latlu + 31.76 * SIN(n + n - f)
	    latlu = latlu + 117.26 * SIN(d + d + f)
	    latlu = latlu + 623.66 * SIN(d + d - f)
	    latlu = latlu + 199.48 * SIN(d + d - n + f)
	    latlu = latlu + 166.58 * SIN(d + d - n - f)
	    latlu = latlu + 33.36 * SIN(d + d + n - f)
	    latlu = latlu + 29.69 * SIN(d + d - m - f)
	    latlu = latlu + 15.56 * SIN(d + d - n - n - f)
	    latlu = latlu + 15.12 * SIN(d + d + n + f)
	    latlu = latlu - 12.44 * SIN(d + d + m - f)
	    latlu = latlu + 8.09 * SIN(d + d - n - m + f)
	    latlu = latlu + 8! * SIN(d + d - m + f)
	    latlu = latlu / 3600
	    latlur = latlu * degrad
	    oe = theme.oblic    '    obliquite ecliptique
	    ci = COS(oe)
	    si = SIN(oe)
	    sdeclu = ci * SIN(latlur) + si * COS(latlur) * SIN(lonlur)
	    declur = ATN(sdeclu / (1 - sdeclu * sdeclu) ^ .5)
	    PlEnsignes(2) = MumSigne%(ll)
	    LongPlanetes(2) = ll
	    LatPlanetes(2) = latlu
	    Decplanetes(2) = declur * radeg
 
	 
	 END SUB

'
'
'
'
'
'
	 FUNCTION MumSigne% (x AS DOUBLE)
	    MumSigne% = INT(x / 30) + 1
	 END FUNCTION

'
'
'
'
'
'
	SUB Pointsfictifs (theme AS typetheme)
	  DIM nal AS DOUBLE, lms AS DOUBLE, nalr AS DOUBLE
	  DIM deuxlr AS DOUBLE, nutalong AS DOUBLE, nutaob AS DOUBLE
	  DIM obl AS DOUBLE
	  DIM deltalambda AS DOUBLE, xsvp AS DOUBLE, xpres AS DOUBLE
	  DIM f AS DOUBLE, d AS DOUBLE, om AS DOUBLE
	  DIM amoys AS DOUBLE, nascl AS DOUBLE, nasclr AS DOUBLE
	  DIM lmpl AS DOUBLE, correc AS DOUBLE
	  DIM lnoire AS DOUBLE, lnoirem AS DOUBLE
	  DIM t AS DOUBLE, nj AS DOUBLE
	  DIM TU AS DOUBLE, lo AS DOUBLE
	  DIM ts0h AS DOUBLE, tsh AS DOUBLE, tsr AS DOUBLE, tsdeg AS DOUBLE
	    t = theme.t0
	    nj = theme.n0
	    TU = theme.htu              ' TU en heures decimales
	    lo = theme.lonheur          'longitude du lieu en heures decimales
	    'armc
	    ts0h = 6.646065556# + 2400.051262# * t + .000025805# * t * t
	    tsh = ts0h + TU + lo
	    tsh = Z24#(tsh)
	    tsdeg = Z360#(tsh * 15#)
	    tsrad = tsdeg * degrad
	    theme.armc = tsrad
	    'Noeud AS lune
	    nal = 259.183275# - 1934.1420083# * t + .0020777# * t * t
	    nal = Z360#(nal)
	    nalr = nal * degrad
	    'longitude moyenne soleil (en degres)
	    lms = 279.69668# + .9856473354# * nj + .000303# * t * t
	    lms = Z360#(lms)
	    '2 fois longitude moyenne soleil (en radians)
	    deuxlr = lms * 2! * degrad
	    'nutation en longitude (en secondes)
	    nutalong = -17.23 * SIN(nalr) - 1.27 * SIN(deuxlr)
	    'nutation en obliquite (en secondes)
	    nutaob = 9.21 * COS(nalr) + .55 * COS(deuxlr)
	    'obliquite de l'ecliptique
	    obl = (23.452294# - .013013# * t + nutaob / 3600#) * degrad
	    theme.oblic = obl
	    ' correction pour noeud as et lune noire
	    f = .196364085# + 8433.466288# * t - .000055754# * t * t
	    d = 6.1215241855# + 7771.377193# * t - .0000242407# * t * t
	    'anomalie moyenne soleil
	    om = 281.22083# + .0000470684# * nj + .000453# * t * t
	    om = om + .000003# * t * t * t
	    amoys = lms - om
	    amoys = amoys * degrad

	    'noeud as lune moyen
	    PlEnsignes(15) = MumSigne%(nalr * radeg)
	    LongPlanetes(15) = nalr * radeg

	    'noeud as lune corrige
	    nascl = nalr + .026470826# * SIN(2# * (f - d))
	    nascl = nascl * radeg
	    PlEnsignes(13) = MumSigne%(nascl)
	    LongPlanetes(13) = nascl
	 
	    'longitude moyenne perigee lunaire (en degres)
	    lmpl = 334.44 + .111404 * nj - .0010313# * t * t
	    lnoirem = Z360#(lmpl + 180#)

	    'lune noire corrigee !!! DOIT AS ETRE BON!!!!
	    correc = 5.8 * SIN(2 * (amoys - lmpl * degrad))
	    lnoire = Z360#(lnoirem + correc)
	    PlEnsignes(14) = MumSigne%(lnoire)
	    LongPlanetes(14) = lnoire

	    'lune noire moyenne
	    PlEnsignes(16) = MumSigne%(Z360#(lnoirem))
	    LongPlanetes(16) = Z360#(lnoirem)
	 
	END SUB

'
'
'
'
'
'
	 SUB Rapides (theme AS typetheme)
	   DIM a AS DOUBLE, e AS DOUBLE, i AS DOUBLE
	   DIM m  AS DOUBLE, w AS DOUBLE, d AS DOUBLE
	   DIM lg AS DOUBLE, lt AS DOUBLE, dec AS DOUBLE
	   DIM t AS DOUBLE
	    t = theme.t0

	    'Mercure
	    a = .387099#
	    e = .205614# + .000002 * t#
	    i = .122223# + .000032# * t
	    m = 1.785112# + 2608.787533# * t
	    w = 1.3247# + .027148# * t
	    d = .822852# + .020686# * t
	    Coordonn theme, a, e, i, m, w, d, lg, lt, dec
	    lg = Z360#(lg * radeg)
	    PlEnsignes(3) = MumSigne%(lg)
	    LongPlanetes(3) = lg
	    LatPlanetes(3) = lt * radeg
	    Decplanetes(3) = dec * radeg

	    'Venus
	    a = .723332#
	    e = .006821# - .000048# * t
	    i = .05923# + .000018# * t
	    m = 3.710626# + 1021.328349# * t
	    w = 2.271787# + .024755# * t
	    d = 1.322604# + .015705# * t
	    Coordonn theme, a, e, i, m, w, d, lg, lt, dec
	    lg = Z360#(lg * radeg)
	    PlEnsignes(4) = MumSigne%(lg)
	    LongPlanetes(4) = lg
	    LatPlanetes(4) = lt * radeg
	    Decplanetes(4) = dec * radeg

	  
	    ' Mars
	    a = 1.523688#
	    e = .093313# + .000092# * t
	    i = .032294# - .000012# * t
	    m = 5.576661# + 334.053484# * t
	    w = 5.8330806# + .032127# * t
	    d = .851484# + .013456# * t
	    Coordonn theme, a, e, i, m, w, d, lg, lt, dec
	    lg = Z360#(lg * radeg)
	    PlEnsignes(5) = MumSigne%(lg)
	    LongPlanetes(5) = lg
	    LatPlanetes(5) = lt * radeg
	    Decplanetes(5) = dec * radeg
	  
	 END SUB

'
'
'
'
'
'
	 SUB Saspects (theme AS typetheme)
	   DIM p1 AS INTEGER, p2 AS INTEGER
	   DIM a AS SINGLE, lp1 AS SINGLE, lp2 AS SINGLE, obasr AS SINGLE
	   DIM obasi AS INTEGER
	   DIM Aspect AS INTEGER
	   DIM oco AS SINGLE, otc AS SINGLE, os AS SINGLE
		FOR p1 = 1 TO 13
		  FOR p2 = p1 TO 14
		    aspects(p1, p2) = -1
		    a = LongPlanetes(p1) - LongPlanetes(p2)
		    IF (a < 0!) THEN a = a + 360!
		    IF (a > 180!) THEN a = 360! - a
		    oco = orbes(conj, p1, p2)
		    otc = orbes(car, p1, p2)
		    os = orbes(sext, p1, p2)
		    IF (a <= oco) THEN
			   aspects(p1, p2) = 8000 + INT(a * 10)
		    END IF
		    IF ((a <= 180! + oco) AND (a >= 180! - oco)) THEN
			  obasr = ABS(180! - a)
			  aspects(p1, p2) = 7000 + INT(obasr * 10)
		    END IF
		    IF ((a <= 120! + otc) AND (a >= 120! - otc)) THEN
			  obasr = ABS(120! - a)
			  aspects(p1, p2) = 6000 + INT(obasr * 10)
		    END IF
		    IF ((a <= 90! + otc) AND (a >= 90! - otc)) THEN
			  obasr = ABS(90! - a)
			  aspects(p1, p2) = 5000 + INT(obasr * 10)
		    END IF
		    IF ((a <= 60! + os) AND (a >= 60! - os)) THEN
			  obasr = ABS(60! - a)
			  aspects(p1, p2) = 2000 + INT(obasr * 10)
		    END IF
		  NEXT p2
		NEXT p1
	 END SUB

'
'
'
'
'
'
	 SUB Soleil (theme AS typetheme)
	   DIM l AS DOUBLE, deuxl AS DOUBLE
	   DIM e AS DOUBLE, om AS DOUBLE, u AS DOUBLE
	   DIM m AS DOUBLE, rsol AS DOUBLE, v AS DOUBLE
	   DIM a AS DOUBLE, b AS DOUBLE, c AS DOUBLE, d AS DOUBLE
	   DIM f AS DOUBLE, g AS DOUBLE, h AS DOUBLE
	   DIM j AS DOUBLE, n2 AS DOUBLE, k AS DOUBLE
	   DIM p AS DOUBLE, q AS DOUBLE, r AS DOUBLE, dt AS DOUBLE
	   DIM nalune AS DOUBLE, nutation AS DOUBLE
	   DIM abberation AS DOUBLE, ls AS DOUBLE, ls0 AS DOUBLE
	   DIM xx AS SINGLE, min1 AS SINGLE, sec1 AS SINGLE
	   DIM i AS INTEGER, xxi AS INTEGER, deg AS INTEGER
	   DIM min AS INTEGER, sec AS INTEGER, nums AS INTEGER
	   DIM t AS DOUBLE, n AS DOUBLE
	   t = theme.t0
	   n = theme.n0
	   l = 279.69668# + .9856473354# * n + .000303# * t * t ' L moy en deg
	   l = Z360r#(l)
	   deuxl = l * 2#
	   e = .01675104# - .0000418# * t - .000000126# * t * t   ' exentricite
	   om = 281.22083# + .0000470684# * n + .000453# * t * t  ' long noeud
	   om = om + .000003# * t * t * t
	   om = Z360r#(om)
	   m = l - om
	   u = m + e * SIN(m)            ' anomalie exentrique
	   FOR i = 1 TO 11 ' Equation kepler
		  u = m + e * SIN(u)
	   NEXT i
	   rsol = 1.00000023# * (1# - e * COS(u)) ' rayon vecteur
	   v = 2# * ATN(TAN(u / 2#) * SQR((1# + e) / (1# - e)))' Anomalie vraie
	   n2 = n - 364.5
	   a = 17.9 + .6165298# * n2: a = Z360r#(a)
	   b = 306# + 1.2330596# * n2: b = Z360r#(b)
	   c = 115.9 + .2474593# * n2: c = Z360r#(c)
	   d = 222.1 + .858513# * n2: d = Z360r#(d)
	   e = 199.2 - .121611# * n2: e = Z360r#(e)
	   f = 38.3 + .9231589# * n2: f = Z360r#(f)
	   g = 256.9 - .0624422# * n2: g = Z360r#(g)
	   h = 281.6 + .9025161# * n2: h = Z360r#(h)
	   j = 7.6 - .0830856# * n2: j = Z360r#(j)
	   k = 291.4 + 1.80503# * n2: k = Z360r#(k)
	   p = 316# + .8194305# * n2: p = Z360r#(p)
	   q = 114.3 + 12.1907494# * n2: q = Z360r#(q)
	   r = 231.4 + .00055305# * n2: r = Z360r#(r)
	   dt = 134# * COS(a) + 154# * COS(b) + 69# * COS(c)
	   dt = dt + 43# * COS(d) + 28# * COS(e) + 57# * COS(f)
	   dt = dt + 49# * COS(g) + 200# * COS(h) + 72# * COS(j)
	   dt = dt + 76# * COS(k) + 45# * COS(p)
	   dt = dt + 179# * SIN(q) + 178# * SIN(r)
	   dt = dt / 100000#
	   nalune = 259.183275# - 1934.142014# * t + .0020694# * t * t
	   nalune = Z360r#(nalune)
	   nutation = -(17.23 + .017 * t) * SIN(nalune)
	   nutation = nutation - 1.27 * SIN(deuxl) + .209 * SIN(2! * nalune)
	   abberation = -20.47 / rsol
	   ls0 = (v + om) * radeg
	   ls = (v + om) * radeg + dt + abberation / 3600! + nutation / 3600!
	   theme.xsol = rsol * COS(ls * degrad)
	   theme.ysol = rsol * SIN(ls * degrad)
	   Decplanetes(1) = radeg * Asin#(SIN(theme.oblic) * SIN(ls * degrad))
	   ls = Z360#(ls)
	   PlEnsignes(1) = MumSigne%(ls)
	   LongPlanetes(1) = ls
	   LatPlanetes(1) = 0
    END SUB

'
'
'
'
'
'
	SUB Splanmais (theme AS typetheme)
	  DIM pla AS INTEGER, mais AS INTEGER
	  DIM di AS SINGLE, dp AS SINGLE
	  DIM deltam(11) AS SINGLE
	   FOR pla = 1 TO 16
		 FOR mais = 1 TO 12
		    di = LongAngles(mais + 1) - LongAngles(mais)
		    IF (di <= 0) THEN di = di + 360!
		    dp = LongPlanetes(pla) - LongAngles(mais)
		    IF (dp <= 0) THEN dp = dp + 360!
		    IF (dp <= di) THEN PlEnMaisons(pla) = mais
		 NEXT mais
	   NEXT pla
	END SUB

DEFINT A-Z
'
'
'
'
'
'
	 SUB VoirTheme (theme AS typetheme, sortie AS INTEGER)
	   DIM sg AS INTEGER, dg AS INTEGER, mn AS INTEGER
	   DIM dg1 AS INTEGER, mn1 AS INTEGER
	   DIM dg2 AS INTEGER, mn2 AS INTEGER
	   DIM dg3 AS INTEGER, mn3 AS INTEGER
	   DIM dg4 AS INTEGER, mn4 AS INTEGER
	   DIM pas AS SINGLE
	   DIM lg AS SINGLE, lt AS SINGLE, dec AS SINGLE
	   DIM ht AS SINGLE, az AS SINGLE, ar AS SINGLE
	   DIM i AS INTEGER, plm AS INTEGER
	   DIM p1 AS INTEGER, p2 AS INTEGER, asp AS INTEGER
	   DIM typas AS INTEGER, orbe AS SINGLE
	   DIM indic AS STRING * 1
		PRINT #sortie, "": PRINT #sortie, "": PRINT #sortie, ""
		FOR i = 1 TO 16
		   sg = PlEnsignes(i)
		   lg = LongPlanetes(i) - (sg - 1) * 30
		   dg = INT(lg)
		   mn = (lg - dg) * 60
		   IF (i < 11) THEN
			 pas = PasPlanetes(i)
			 signe = SGN(pas)
			 dg1 = INT(ABS(pas))
			 mn1 = (ABS(pas) - dg1) * 60
			 IF (pas < 0) THEN
			    indic = "R"
			  ELSE
			    indic = " "
			 END IF
			 PRINT #sortie, USING format11; plan(i); dg; mn; signe(sg); indic; dg1; mn1
		    ELSE
			 PRINT #sortie, USING format1; plan(i); dg; mn; signe(sg)
		   END IF
		NEXT i
		IF (sortie = ecran) THEN a$ = INPUT$(1)
		PRINT #sortie, CHR$(12) 'CLS
		PRINT #sortie, "": PRINT #sortie, "": PRINT #sortie, ""
		FOR i = 1 TO 12
		   sg = AnglesEnSignes(i)
		   lg = LongAngles(i) - (sg - 1) * 30
		   dg = INT(lg)
		   mn = (lg - dg) * 60
		   PRINT #sortie, USING format2; i; dg; mn; signe(sg)
		NEXT i
		IF (sortie = ecran) THEN a$ = INPUT$(1)
		PRINT #sortie, CHR$(12) 'CLS
		PRINT #sortie, "": PRINT #sortie, "": PRINT #sortie, ""
		FOR i = 1 TO 10
		   lt = LatPlanetes(i)
		   dg = INT(ABS(lt))
		   mn = (ABS(lt) - dg) * 60
		   dec = Decplanetes(i)
		   dg1 = INT(ABS(dec))
		   mn1 = (ABS(dec) - dg1) * 60
 
		   ar = ArPlanetes(i)
		   dg2 = INT(ABS(ar))
		   mn2 = (ABS(ar) - dg2) * 60

		   ht = HautPlanetes(i)
		   dg3 = INT(ABS(ht))
		   mn3 = (ABS(ht) - dg3) * 60

		   az = AziPlanetes(i)
		   dg4 = INT(ABS(az))
		   mn4 = (ABS(az) - dg4) * 60
		   PRINT #sortie, USING format5; plan(i); dg * SGN(lt); mn; dg1 * SGN(dec); mn1; dg2 * SGN(ar); mn2; dg3 * SGN(ht); mn3; dg4 * SGN(az); mn4
		NEXT i
		IF (sortie = ecran) THEN a$ = INPUT$(1)
		PRINT #sortie, CHR$(12) 'CLS
		PRINT #sortie, "": PRINT #sortie, "": PRINT #sortie, ""
		FOR i = 1 TO 10
		  plm = PlEnMaisons(i)
		  PRINT #sortie, USING format3; plan(i); plm
		NEXT i
		FOR i = 13 TO 16
		   plm = PlEnMaisons(i)
		   PRINT #sortie, USING format3; plan(i); plm
		NEXT i
		IF (sortie = ecran) THEN a$ = INPUT$(1)
		PRINT #sortie, CHR$(12) 'CLS
		PRINT #sortie, "": PRINT #sortie, "": PRINT #sortie, ""
		FOR p1 = 1 TO 13
		  FOR p2 = p1 + 1 TO 14
			asp = aspects(p1, p2)
			IF (asp > 0) THEN
			 typas = INT(asp / 1000)
			 orbe = (asp - typas * 1000) / 10!
			 PRINT #sortie, USING format4; plan(p1); denoasp(typas); plan(p2); orbe
			 IF (sortie = ecran) THEN a$ = INPUT$(1)
			END IF
		  NEXT p2
	    NEXT p1
	    IF (sortie = ecran) THEN a$ = INPUT$(1)
	 END SUB

DEFSNG A-Z
'
'
'
'
'
'
	 FUNCTION Z24# (x AS DOUBLE)
	   DIM nn AS INTEGER, xx AS DOUBLE
		nn = INT(x / 24!)
		xx = x - nn * 24#
		IF (xx < 0) THEN xx = xx + 24#
		Z24# = xx
	  END FUNCTION

'
'
'
'
'
'
	 FUNCTION Z360# (x AS DOUBLE)
	   DIM nn AS INTEGER, xx AS DOUBLE
		nn = INT(x / 360#)
		xx = x - nn * 360#
		IF (xx < 0) THEN xx = xx + 360#
		Z360# = xx
    END FUNCTION

'
'
'
'
'
'
	 FUNCTION Z360r# (x AS DOUBLE)
	    DIM nn AS INTEGER, xx AS DOUBLE
		 nn = INT(x / 360#)
		 xx = x - nn * 360#
		 IF (xx < 0) THEN xx = xx + 360#
		 Z360r# = xx * degrad
	END FUNCTION

'
'
'
'
'
'
	 FUNCTION z360s! (x AS SINGLE)
	    z360s! = 360! + x! - INT((360! + x!) / 360!) * 360!
	 END FUNCTION

========================FICHIER DE DONNEES ORBES.TXT ===========
13
14
2
-1
1  2  3  4  5  6  7  8  9 10 11 12 13 14
so lu me ve ma ju sa ur ne pl as mc nl ln
0,15, 8, 8,15,15,15,15,15,15,15,15,10,10 ' so
0, 0, 8, 8,15,15,15,15,10,15,15,15,10,10 ' lu
0, 0, 0,12,12,12,12,12,12,12,12,12,10,10 ' me
0, 0, 0, 0,12,12,12,12,12,12,12,12,10,10 ' ve
0, 0, 0, 0, 0,12,12,12,12,12,12,12,10,10 ' ma
0, 0, 0, 0, 0, 0,10,10,10,10,12,12, 8, 8 ' ju
0, 0, 0, 0, 0, 0, 0,10,10,10,12,12, 8, 8 ' sa
0, 0, 0, 0, 0, 0, 0, 0,10,10,12,12, 8, 8 ' ur
0, 0, 0, 0, 0, 0, 0, 0, 0,10,12,12, 8, 8 ' ne
0, 0, 0, 0, 0, 0, 0, 0, 0, 0,12,12, 8, 8 ' pl
0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0,10,10 ' as
0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0,10,10 ' mc
0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0,10 ' nl
1  2  3  4  5  6  7  8  9 10 11 12 13 14
so lu me ve ma ju sa ur ne pl as mc nl ln
0, 8, 5, 5, 8, 8, 8, 8, 8, 8, 8, 8, 6, 6  'so
0, 0, 5, 5, 8, 8, 8, 8, 6, 8, 8, 8, 6, 6  'lu
0, 0, 0, 7, 7, 7, 7, 7, 7, 7, 7, 7, 6, 6  'me
0, 0, 0, 0, 7, 7, 7, 7, 7, 7, 7, 7, 6, 6  've
0, 0, 0, 0, 0, 7, 7, 7, 7, 7, 7, 7, 6, 6  'ma
0, 0, 0, 0, 0, 0, 6, 6, 6, 6, 7, 7, 5, 5  'ju
0, 0, 0, 0, 0, 0, 0, 6, 6, 6, 7, 7, 5, 5  'sa
0, 0, 0, 0, 0, 0, 0, 0, 6, 6, 7, 7, 5, 5  'ur
0, 0, 0, 0, 0, 0, 0, 0, 0, 6, 7, 7, 5, 5  'ne
0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 7, 7, 5, 5  'pl
0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 6, 6  'as
0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 6, 6  'mc
0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 6  'nl
1  2  3  4  5  6  7  8  9 10 11 12 13 14
so lu me ve ma ju sa ur ne pl as mc nl ln
0, 3, 2, 2, 3, 3, 3, 3, 3, 3, 3, 3, 2, 2 'so
0, 0, 2, 2, 3, 3, 3, 3, 2, 3, 3, 3, 2, 2 'lu
0, 0, 0, 3, 3, 3, 3, 3, 3, 3, 3, 3, 2, 2 'me
0, 0, 0, 0, 3, 3, 3, 3, 3, 3, 3, 3, 2, 2 've
0, 0, 0, 0, 0, 3, 3, 3, 3, 3, 3, 3, 2, 2 'ma
0, 0, 0, 0, 0, 0, 2, 2, 2, 2, 3, 3, 2, 2 'ju
0, 0, 0, 0, 0, 0, 0, 2, 2, 2, 3, 3, 2, 2 'sa
0, 0, 0, 0, 0, 0, 0, 0, 2, 2, 3, 3, 2, 2 'ur
0, 0, 0, 0, 0, 0, 0, 0, 0, 2, 3, 3, 2, 2 'ne
0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 3, 3, 2, 2 'pl
0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 2, 2 'as
0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 2, 2 'mc
0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 2 'nl


==========================  SORTIES DE PROGRAMME =====================
     pour:
    'J.M. BIGARD
     theme.jour = 17
     theme.mois = 5
     theme.annee = 1954
     theme.heure = 10.5  '(11H30 LEG, 10h30 TU)
     theme.htu = theme.heure 'htu est un 'double' heure est un 'single'
     theme.latrad = 48.3 * degrad  '(48ø18')
     theme.lonheur = .272  '(4ø05' Est)  en heures (<0 si Ouest)
     '4ø 05'= 4.083ø= 4.083 * 4 = 16.33 minutes = 16.33/60 = 0.272 heures

=======================================================================

     Soleil              :  25ø 59'  Taureau         (Pas=   0ø58')
     Lune                :  20ø 46'  Scorpion        (Pas=  12ø 2')
     Mercure             :   6ø  3'  Gemeaux         (Pas=   2ø 4')
     Venus               :  22ø 32'  Gemeaux         (Pas=   1ø13')
     Mars                :   8ø 14'  Capricorne      (Pas=   0ø 4')
     Jupiter             :  28ø 30'  Gemeaux         (Pas=   0ø13')
     Saturne             :   4ø 35'  Scorpion     R  (Pas=   0ø 4')
     Uranus              :  20ø  9'  Cancer          (Pas=   0ø 2')
     Neptune             :  23ø 52'  Balance      R  (Pas=   0ø 1')
     Pluton              :  22ø 32'  Lion            (Pas=   0ø 0')
     Ascendant           :  20ø 45'  Lion         
     Milieu du Ciel      :   8ø 33'  Taureau      
     Noeud As Lune Corr. :  16ø  4'  Capricorne   
     Lune Noire corr.    :  23ø 56'  Balance      
     Noeud As Lune moy.  :  17ø 31'  Capricorne   
     Lune Noire moy.     :  26ø 55'  Balance      




	  Maison   1:    20ø 45'  Lion        
	  Maison   2:    10ø 27'  Vierge      
	  Maison   3:     5ø 47'  Balance     
	  Maison   4:     8ø 33'  Scorpion    
	  Maison   5:    16ø 41'  Sagittaire  
	  Maison   6:    22ø  2'  Capricorne  
	  Maison   7:    20ø 45'  Verseau     
	  Maison   8:    10ø 27'  Poissons    
	  Maison   9:     5ø 47'  Belier      
	  Maison  10:     8ø 33'  Taureau     
	  Maison  11:    16ø 41'  Gemeaux     
	  Maison  12:    22ø  2'  Cancer      




   Soleil     Lat=  0ø 0' Dec=  19ø15' AR=  53ø39' Haut=  57ø42' Az=  32ø 4'
   Lune       Lat= -4ø11' Dec= -21ø59' AR= 227ø 9' Haut= -62ø16' Az= 202ø18'
   Mercure    Lat=  1ø24' Dec=  22ø42' AR=  63ø55' Haut=  56ø14' Az=  50ø35'
   Venus      Lat=  1ø11' Dec=  24ø25' AR=  81ø48' Haut=  47ø 5' Az=  72ø53'
   Mars       Lat= -1ø47' Dec= -24ø58' AR= 279ø 5' Haut= -36ø 8' Az= 268ø 4'
   Jupiter    Lat=  0ø 6' Dec=  23ø20' AR=  88ø22' Haut=  42ø 4' Az=  77ø49'
   Saturne    Lat=  2ø41' Dec= -10ø32' AR= 213ø14' Haut= -52ø 9' Az= 175ø18'
   Uranus     Lat=  0ø28' Dec=  22ø24' AR= 111ø52' Haut=  25ø53' Az=  95ø18'
   Neptune    Lat=  1ø45' Dec=  -7ø38' AR= 202ø45' Haut= -47ø47' Az= 159ø59'
   Pluton     Lat=  9ø54' Dec=  23ø21' AR= 148ø23' Haut=   3ø43' Az= 121ø36'




	  Soleil          en  Maison  10
	  Lune            en  Maison   4
	  Mercure         en  Maison  10
	  Venus           en  Maison  11
	  Mars            en  Maison   5
	  Jupiter         en  Maison  11
	  Saturne         en  Maison   3
	  Uranus          en  Maison  11
	  Neptune         en  Maison   3
	  Pluton          en  Maison   1
	  Noeud As Lune C en  Maison   5
	  Lune Noire corr en  Maison   3
	  Noeud As Lune m en  Maison   5
	  Lune Noire moy. en  Maison   3




   Soleil          Opposition    Lune                (orbe:   5.2ø)
   Soleil          Carre         Pluton              (orbe:   3.4ø)
   Soleil          Carre         Ascendant           (orbe:   5.2ø)
   Lune            Trigone       Uranus              (orbe:   0.6ø)
   Lune            Carre         Pluton              (orbe:   1.7ø)
   Lune            Carre         Ascendant           (orbe:   0.0ø)
   Lune            Opposition    Milieu du Ciel      (orbe:  12.2ø)
   Venus           Conjonction   Jupiter             (orbe:   5.9ø)
   Venus           Trigone       Neptune             (orbe:   1.3ø)
   Venus           Sextile       Pluton              (orbe:   0.0ø)
   Venus           Sextile       Ascendant           (orbe:   1.7ø)
   Venus           Trigone       Lune Noire corr.    (orbe:   1.3ø)
   Mars            Opposition    Jupiter             (orbe:   9.7ø)
   Mars            Opposition    Uranus              (orbe:  11.9ø)
   Mars            Trigone       Milieu du Ciel      (orbe:   0.3ø)
   Mars            Conjonction   Noeud As Lune Corr. (orbe:   7.8ø)
   Jupiter         Trigone       Neptune             (orbe:   4.6ø)
   Jupiter         Trigone       Lune Noire corr.    (orbe:   4.5ø)
   Saturne         Opposition    Milieu du Ciel      (orbe:   3.9ø)
   Uranus          Carre         Neptune             (orbe:   3.7ø)
   Uranus          Opposition    Noeud As Lune Corr. (orbe:   4.0ø)
   Uranus          Carre         Lune Noire corr.    (orbe:   3.7ø)
   Neptune         Sextile       Pluton              (orbe:   1.3ø)
   Neptune         Conjonction   Lune Noire corr.    (orbe:   0.0ø)
   Pluton          Conjonction   Ascendant           (orbe:   1.7ø)
   Pluton          Sextile       Lune Noire corr.    (orbe:   1.3ø)